Solidity - Call

call is a low level function to interact with other contracts.
call은 다른 계약과 상호 작용하기 위핸 저수준의 함수이다. 

This is the recommended method to use when you're just sending Ether via calling the fallback function.
이 방법은 fallback 함수를 호출하여 Ether를 전송할 때 사용하는 권장하는 방법이다.

However it is not the recommend way to call existing functions.
그러나 기존에 존재하는 함수를 호출하는 권장하는 방법은 아닙니다. 

Few reasons why low-level call is not recommended
저 수준의 call이 권장되지않는 몇 가지 이유

• Reverts are not bubbled up 
• Type checks are bypassed 
• Function existence checks are omitted

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

contract Receiver {
    event Received(address caller, uint amount, string message);

    fallback() external payable {
        emit Received(msg.sender, msg.value, "Fallback was called");
    }

    function foo(string memory _message, uint _x) public payable returns (uint) {
        emit Received(msg.sender, msg.value, _message);

        return _x + 1;
    }
}

contract Caller {
    event Response(bool success, bytes data);

    // Let's imagine that contract Caller does not have the source code for the
    // contract Receiver, but we do know the address of contract Receiver and the function to call.
    function testCallFoo(address payable _addr) public payable {
        // You can send ether and specify a custom gas amount
        (bool success, bytes memory data) = _addr.call{value: msg.value, gas: 5000}(
            abi.encodeWithSignature("foo(string,uint256)", "call foo", 123)
        );

        emit Response(success, data);
    }

    // Calling a function that does not exist triggers the fallback function.
    function testCallDoesNotExist(address payable _addr) public payable {
        (bool success, bytes memory data) = _addr.call{value: msg.value}(
            abi.encodeWithSignature("doesNotExist()")
        );

        emit Response(success, data);
    }
}

Try on Remix

• Call.sol

Remix - Ethereum IDE