ERC-721(NFT) Solidity 코드 및 토큰 분석

 

1. ERC-721(Ethereum Request for Comment-721) 토큰이란?

 

ERC-721 토큰은 다른 말로 대체 불가능한 토큰 (Non-Fungible Token)이라고 부르기도 합니다. 그리고 ERC-721은 NFT를 구현하는데 필요한 표준을 정의합니다. 이 표준은 EIP-721에서 논의됐습니다.(하단 링크 참고) 
그리고 ERC는 자신의 아이디어를 제안하고 어떤지 평가를 해달라고 한 뒤 많은 사람들이 괜찮다고 생각하면 선택하는 표준 같은거라고 생각하시면 됩니다. 그렇다면 왜 NFT라고 부르는 것이고 NFT 함수들은 어떤 것이 있을까요??  2. ERC-721 토큰함수에서 살펴보시면 됩니다. 

 

EIP-721 (EIP는 Ethereum Improvement Proposals의 약자입니다. )

https://eips.ethereum.org/EIPS/eip-721

ERC-721: Non-Fungible Token Standard

 

 

2. ERC-721 토큰의 주요 상태변수 및 주요 함수 

 

2-1 상태 변수

//라이브러리 호출 방법이다.
//using 라이브러리 이름 for 데이터 타입
using Address for address;
using Strings for uint256;

// 토큰 이름 비트코인이나 이더리움 이름을 여기다 쓰면 된다.
string private _name;

// 토큰의 심볼이다 BTC나 ETH 같은 것으로 이해하면 된다.
// 이름이 Bored Ape Yacht Club면 심볼은 BAYC다.
string private _symbol;

// 각 토큰의 ID와 토큰 소유자의 주소를 매핑한다.
mapping(uint256 => address) private _owners;

// 토큰 소유자 주소와 토큰 소유자가 가진 토큰 개수를 매핑함
mapping(address => uint256) private _balances;

// 토큰 ID와 approved된 주소를 매핑한다. (approved는 승인 개념이라고 보면된다. )
mapping(uint256 => address) private _tokenApprovals;

// 토큰 소유자와 operator주소의 approval 여부를 저장한다.
// 최초 소유자가 다른 운영자에게 권한을 주면 true 권한을 취소하면 false라고 보면된다.
mapping(address => mapping(address => bool)) private _operatorApprovals;

2-2 생성자 함수

//이름과 심볼로 컨스트럭터를 설정한다.
//생성자함수다. 컨트랙트가 생성될 때 생성자함수가 실행되며 컨트랙트 상태가 초기화됨
// selfdestruct도 있다. 현재 컨트랙트를 소멸시키는 기능이다.
// selfdestruct(컨트랙트 생성자의 주소);
constructor(string memory name_, string memory symbol_) {
_name = name_;
_symbol = symbol_;
}

 

 

2-3 주요 함수

    //  owner 주소가 가지고 있는 NFT의 개수를 반환합니다.
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: address zero is not a valid owner");
        return _balances[owner];
    }


    // 모든 NFT는 발행된 컨트랙트 내에 고유한 토큰아이디가 있다. 
    // 컨트랙트 주소와 토큰 아이디만 있으면 NFT 정보에 접근할 수 있다.
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _ownerOf(tokenId);
        require(owner != address(0), "ERC721: invalid token ID");
        return owner;
    }
    
    //approve 함수는 토큰아이디를 제 3자가 사용할 수 있도록 승인하는 함수다.
     //approve를 통해 tokenId 사용을 승인 받은 제 3자는 operator라고 부르며
     //operator는 이 tokenId를 다른 스마트 컨트랙트에 사용하거나 다시 approve할 수 있다. 
     //approve()함수는 소유권을 승인하는 행위라서 tokenId의 owner나 operator만 호출할 수 있다.
     //이 함수로 보면 NFT의 핵심은 아무래도 tokenId로 보인다. 
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not token owner or approved for all"
        );

        _approve(to, tokenId);
    }
    
    //토큰Id가 누군가에게 approved된 상태면 승인된 operator의 주소를 반환한다. 
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        _requireMinted(tokenId);

        return _tokenApprovals[tokenId];
    }
    
    // 이 함수를 호출한 msg.sender가 컨트랙트에서 가지고 있는 모든 NFT를
    // 특정 operator에게 승인하는 함수다. 
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }
    
    // owner가 operator에게 setApprovalForAll함수를 통해 모든 NFT를 승인했는지 여부를 전달한다.
    // 모든 NFT가 승인되면 true, 아니면 false
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }
    
    //from 주소에서 to 주소로 토큰 아이디를 옮긴다. 
    //from에는 토큰의 owner나 operator만 올 수 있다. 
    function transferFrom(address from, address to, uint256 tokenId) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");

        _transfer(from, to, tokenId);
    }
    
    //NFT를 받는 주소가 NFT를 받을 수 있는 주소인지 확인하는 함수다. 
    //trasferfrom함수는 받는 주소가 NFT를 사용할 수 있는지 확인하지 않고 보내기 때문에
    //trasferfrom함수는 잘못 사용하면 NFT를 버릴수도 있다.
    function safeTransferFrom(address from, address to, uint256 tokenId) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }
    
    
    //NFT를 받는 주소가 NFT를 받을 수 있는 주소인지 확인하는 함수다. 
    //trasferfrom함수는 받는 주소가 NFT를 사용할 수 있는지 확인하지 않고 보내기 때문에
    //trasferfrom함수는 잘못 사용하면 NFT를 버릴수도 있다.
    function safeTransferFrom(address from, address to, uint256 tokenId) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

 

3. 오픈 제플린의 ERC721 토큰 솔리디티 코드

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    //라이브러리 호출 방법이다.
    //using 라이브러리 이름 for 데이터 타입
    using Address for address;
    using Strings for uint256;

    // Token name
    // 토큰 이름 비트코인이나 이더리움 이름을 여기다 쓰면 된다. 
    string private _name;

    // Token symbol
    // 토큰의 심볼이다 BTC나 ETH 같은 것으로 이해하면 된다. 
    // 이름이 Bored Ape Yacht Club면 심볼은 BAYC다. 
    string private _symbol;

    // Mapping from token ID to owner address
    // 각 토큰의 ID와 토큰 소유자의 주소를 매핑한다. 
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    // 토큰 소유자 주소와 토큰 소유자가 가진 토큰 개수를 매핑함 
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    // 토큰 ID와 approved된 주소를 매핑한다. (approved는 승인 개념이라고 보면된다. )
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    // 토큰 소유자와 operator주소의 approval 여부를 저장한다. 
    // 최초 소유자가 다른 운영자에게 권한을 주면 true 권한을 취소하면 false라고 보면된다. 
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
     //이름과 심볼로 컨스트럭터를 설정한다. 
     //생성자함수다. 컨트랙트가 생성될 때 생성자함수가 실행되며 컨트랙트 상태가 초기화됨
     // selfdestruct도 있다. 현재 컨트랙트를 소멸시키는 기능이다. 
     // selfdestruct(컨트랙트 생성자의 주소);
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
     //  owner 주소가 가지고 있는 NFT의 개수를 반환합니다.
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: address zero is not a valid owner");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
     // 모든 NFT는 발행된 컨트랙트 내에 고유한 토큰아이디가 있다. 
     // 컨트랙트 주소와 토큰 아이디만 있으면 NFT 정보에 접근할 수 있다.
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _ownerOf(tokenId);
        require(owner != address(0), "ERC721: invalid token ID");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
     // 메타데이터 - 이름
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
     // 메타데이터 - 심볼
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
     // 메타 데이터에서 읽을 tokenURI다. 
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        _requireMinted(tokenId);

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overridden in child contracts.
     */
    //토큰 URI를 연산한 것으로 보면 된다. 
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
     //approve 함수는 토큰아이디를 제 3자가 사용할 수 있도록 승인하는 함수다.
     //approve를 통해 tokenId 사용을 승인 받은 제 3자는 operator라고 부르며
     //operator는 이 tokenId를 다른 스마트 컨트랙트에 사용하거나 다시 approve할 수 있다. 
     //approve()함수는 소유권을 승인하는 행위라서 tokenId의 owner나 operator만 호출할 수 있다.
     //이 함수로 보면 NFT의 핵심은 아무래도 tokenId로 보인다. 
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not token owner or approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
     //토큰Id가 누군가에게 approved된 상태면 승인된 operator의 주소를 반환한다. 
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        _requireMinted(tokenId);

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
     // 이 함수를 호출한 msg.sender가 컨트랙트에서 가지고 있는 모든 NFT를
     // 특정 operator에게 승인하는 함수다. 
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
     // owner가 operator에게 setApprovalForAll함수를 통해 모든 NFT를 승인했는지 여부를 전달한다.
     // 모든 NFT가 승인되면 true, 아니면 false
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    //from 주소에서 to 주소로 토큰 아이디를 옮긴다. 
    //from에는 토큰의 owner나 operator만 올 수 있다. 
    function transferFrom(address from, address to, uint256 tokenId) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    //NFT를 받는 주소가 NFT를 받을 수 있는 주소인지 확인하는 함수다. 
    //trasferfrom함수는 받는 주소가 NFT를 사용할 수 있는지 확인하지 않고 보내기 때문에
    //trasferfrom함수는 잘못 사용하면 NFT를 버릴수도 있다.
    function safeTransferFrom(address from, address to, uint256 tokenId) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");
        _safeTransfer(from, to, tokenId, data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    //_transfer() 함수를 실행해서 token ID 소유권을 변경한다.
    //require문에 있는 _checkOnERC721Received()함수를 실행한다. 
    //_checkOnERC721Received 함수는 받는 컨트랙트에 onERC721Received()함수가 제대로 구현되었는지 확인한다. 
    
    function _safeTransfer(address from, address to, uint256 tokenId, bytes memory data) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
     */
    function _ownerOf(uint256 tokenId) internal view virtual returns (address) {
        return _owners[tokenId];
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _ownerOf(tokenId) != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || isApprovedForAll(owner, spender) || getApproved(tokenId) == spender);
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(address to, uint256 tokenId, bytes memory data) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId, 1);

        // Check that tokenId was not minted by `_beforeTokenTransfer` hook
        require(!_exists(tokenId), "ERC721: token already minted");

        unchecked {
            // Will not overflow unless all 2**256 token ids are minted to the same owner.
            // Given that tokens are minted one by one, it is impossible in practice that
            // this ever happens. Might change if we allow batch minting.
            // The ERC fails to describe this case.
            _balances[to] += 1;
        }

        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId, 1);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     * This is an internal function that does not check if the sender is authorized to operate on the token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId, 1);

        // Update ownership in case tokenId was transferred by `_beforeTokenTransfer` hook
        owner = ERC721.ownerOf(tokenId);

        // Clear approvals
        delete _tokenApprovals[tokenId];

        unchecked {
            // Cannot overflow, as that would require more tokens to be burned/transferred
            // out than the owner initially received through minting and transferring in.
            _balances[owner] -= 1;
        }
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId, 1);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(address from, address to, uint256 tokenId) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId, 1);

        // Check that tokenId was not transferred by `_beforeTokenTransfer` hook
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");

        // Clear approvals from the previous owner
        delete _tokenApprovals[tokenId];

        unchecked {
            // `_balances[from]` cannot overflow for the same reason as described in `_burn`:
            // `from`'s balance is the number of token held, which is at least one before the current
            // transfer.
            // `_balances[to]` could overflow in the conditions described in `_mint`. That would require
            // all 2**256 token ids to be minted, which in practice is impossible.
            _balances[from] -= 1;
            _balances[to] += 1;
        }
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId, 1);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits an {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits an {ApprovalForAll} event.
     */
    function _setApprovalForAll(address owner, address operator, bool approved) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Reverts if the `tokenId` has not been minted yet.
     */
    function _requireMinted(uint256 tokenId) internal view virtual {
        require(_exists(tokenId), "ERC721: invalid token ID");
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    /// @solidity memory-safe-assembly
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting and burning. If {ERC721Consecutive} is
     * used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s tokens will be transferred to `to`.
     * - When `from` is zero, the tokens will be minted for `to`.
     * - When `to` is zero, ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     * - `batchSize` is non-zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 /* firstTokenId */,
        uint256 batchSize
    ) internal virtual {
        if (batchSize > 1) {
            if (from != address(0)) {
                _balances[from] -= batchSize;
            }
            if (to != address(0)) {
                _balances[to] += batchSize;
            }
        }
    }

    /**
     * @dev Hook that is called after any token transfer. This includes minting and burning. If {ERC721Consecutive} is
     * used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s tokens were transferred to `to`.
     * - When `from` is zero, the tokens were minted for `to`.
     * - When `to` is zero, ``from``'s tokens were burned.
     * - `from` and `to` are never both zero.
     * - `batchSize` is non-zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 firstTokenId, uint256 batchSize) internal virtual {}
}

 

 

참고 : 오픈 제플린 ERC721.sol 코드

 

https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC721/ERC721.sol

GitHub - OpenZeppelin/openzeppelin-contracts: OpenZeppelin Contracts is a library for secure smart contract development.